**Intermediate Logical Functions**

**Swapping values with switches.**

**1.**

Convert the data range in Account Sales History to a table and name the table "Sales".

**Hint**

* Highlight the range from A1 to M2221, navigate to the *Insert* tab, and then click *Table*.
* In the *Create Table* pop-up, confirm the range is from $A$1:$M$2221 and check *My table has headers*, then Click *OK*.
* On the *Table Design* tab, type "Sales" under *Table Name*.

2.

* Create a new column called "Upsell $ Per Non-Paying User", and use the SWITCH() function to find the upsell amounts for non-paying users based on each Subscription Type row.
* When "Basic", non-paying users can be upsold to a "Premium" license for $10.
* When "Premium", non-paying users can be upsold to a paid license for $10.
* When "Business", non-paying users can be upsold to a paid license for $25.
* When "Enterprise", non-paying users can be upsold to a paid license for $27.
* Format this as a $ with 0 decimals.
* In order to perform calculations by rows in tables, the at sign is required before the column name - [@[\_\_\_]].
* Your SWITCH() formula should look like this:

=SWITCH([@[Subscription Type]],"Basic",10,\_\_\_\_,\_\_\_\_,\_\_\_\_,\_\_\_\_,"Enterprise",27)

3.

* Create a new column called "Non-Paying Users" that finds the difference on the row level between the Number of Users and Licenses Bought.
* Use IF() to ensure that any negative difference is changed to zero.

**Hint**

* Subtract Number of Users by Licenses Bought.
* Your formula should look like this:

=IF([@[Number of Users]]-[@[Licenses Bought]]<0,0,\_\_\_)

4.

* Create a new column called "Total Upsell $" that gives us the size of the upsell opportunity based on the Upsell $ Per Non-Paying User and Non-Paying Users.
* Format this as a $ with 0 decimals.
* **Hint**
* Total Upsell $ should be Upsell $ Non-Paying User multiplied by the Non-Paying Users.

5.

**What is the total upsell opportunity? Format your answer as a whole number with 0 decimal places.**

**272473**

**Hint**

* The Upsell $ Per Non-Paying User formula should be:

=SWITCH([@[Subscription Type]],"Basic",10,"Premium",10,"Business",25,"Enterprise",27)

* The Non-Paying Users formula should be:

=IF([@[Number of Users]]-[@[Licenses Bought]]<0,0,[@[Number of Users]]-[@[Licenses Bought]])

* The Total Upsell $ formula should be:

=[@[Non-Paying Users]]\*[@[Upsell $ Per Non-Paying User]]

* Highlight the Total Upsell $ column to find the total sum of the whole column.

*If you're still stuck, review the solution in 2\_1\_switch.xlsx from the Workbooks folder.*

**Nesting logical functions**

1.

Total Upsell $ calculates all the upsell opportunities from each sales month. This isn't helpful in a current analysis because we can't go back in the past.

* Rename the header of Total Upsell $ to Current Upsell $.
* Update the formula to only multiply if the Sales Month is the latest month, otherwise default to 0.

*Hint: Use MAX() to find the latest sales month in the column.*

**Hint**

Your formula should look like this:

=IF([@[Sales Month]]=MAX([Sales Month]),\_\_\_\_\*\_\_\_\_,0)

2.

To help the customer success team, we will create categories for them to work from.

* Create a new column called "Upsell Priority" using an IFS() statement to run this evaluation:
* If Current Upsell $ is 0, make it blank.
* Else if Current Upsell $ is greater than or equal to 400, then High.
* Else if Current Upsell $ is greater than or equal to 100, then Medium.
* Else if Current Upsell $ is less than 100, then Low.

Hint

The IFS() function should look like this:

=IFS(\_\_\_\_=\_\_\_\_,"",[@[Current Upsell $]]>=400,"High",[@[Current Upsell $]]>=100,"Medium",[@[Current Upsell $]]<100,"Low")

3.

We can make a field that is even more informative by using CONCAT() to combine useful information in one string.

* Create a column called "Upsell Account Detail" that combines Subscription Type, Upsell Priority, and Current Upsell $ into a string with spaces in between.
* Use TEXT() on Current Upsell $ to format the string as "$#,#".
* The result of this CONCAT() formula should look like this: Business Medium $150.

**Hint**

* The Upsell Account Detail formula should look like this:
* =CONCAT(\_\_\_\_," ",\_\_\_\_," ",TEXT([@[Current Upsell $]],"$#,#"))

4.

This formula is running on each row, which is pretty noisy.

* Add an IF() statement to Upsell Account Detail that will only CONCAT() if Current Upsell $ is greater than 0.
* Set the the default to be blank.

**Hint**

* The final formula should look like this:
* =IF(\_\_\_\_>\_\_\_\_,CONCAT([@[Subscription Type]]," ",[@[Upsell Priority]]," ",TEXT([@[Current Upsell $]],"$#,#")),"")

5.

Which Customer ID has the highest upsell amount in the Basic High subscription category? Use the filters to sort the data and find out!

100370

**Hint**

**Find the answer:**

* Filter the Upsell Account Detail and search for "Basic High" then click OK.
* Sort the Upsell Account Detail from *Z to A*.
* Look for the Customer ID associated with that row.

**Formulas:** The Current Upset $ formula should be:

=IF([@[Sales Month]]=MAX([Sales Month]),[@[Non-Paying Users]]\*[@[Upsell $ Per Non-Paying User]],0)

The Upsell Priority formula should be:

=IFS([@[Current Upsell $]]=0,"",[@[Current Upsell $]]>=400,"High",[@[Current Upsell $]]>=100,"Medium",[@[Current Upsell $]]<100,"Low")

The Upsell Account Detail formula should be:

=IF([@[Current Upsell $]]>0,CONCAT([@[Subscription Type]]," ",[@[Upsell Priority]]," ",TEXT([@[Current Upsell $]],"$#,#")),"")

*If you're still stuck, review the solution in 2\_2\_nesting\_logical\_functions.xlsx from the Workbooks folder.*

**Using COUNTIF and SUMIF**

1.

First, let's create a new sheet to start a fresh analysis.

* Create a new sheet and rename it "Sales Trends".

**Hint**

* Click on the + on the bottom ribbon to add another *worksheet*.
* Double click on the new *worksheet* tab and type "Sales Trends".

2.

Let's start our sheet with a list of the last 12 months of sales.

* In cell A1 type "Sales Month".
* In cells A2:A13, create list of months starting with 7/1/2020 and ending at 6/1/2021.

*Hint*

*Type the first two dates, then highlight them and then drag the rows down to auto-fill the rest of the dates.*

Your list should look like this (you can copy and paste this into excel).

| **Sales Month** |
| --- |
| 7/1/2020 |
| 8/1/2020 |
| 9/1/2020 |
| 10/1/2020 |
| 11/1/2020 |
| 12/1/2020 |
| 1/1/2021 |
| 2/1/2021 |
| 3/1/2021 |
| 4/1/2021 |
| 5/1/2021 |
| 6/1/2021 |

3.

* Convert this data range to a table using the first row as headers.
* Rename the table to "Sales\_Trends".

**Hint**

* Highlight the range from A1 to A13 by clicking Ctrl + A.
* In the *Insert* tab, click *Table*.
* In the *Create Table* pop-up, confirm the range is from $A$1:$A$13 and check *My table has headers*, then click *OK*.
* On the *Table Design* tab, type "Sales\_Trends" under \_Table Name\_.

4.

Great, now we can start aggregating our data. Count the number of customers per month. Remember that the Account Sales History gives a record of each Customer ID for each Sales Month.

* Create a new column called "Number of Customers" that uses COUNTIF() to count the number of customers within the Sales Month.

*Hint: You will need to reference the Sales Month column in this worksheet, as well as in the Account Sales History worksheet.*

**Hint**

* The COUNTIF() formula should look like this: =COUNTIF(Sales[\_\_\_\_],[@[\_\_\_\_]])
* The first month, 7/1/2020, should have 76 customers.

5.

Nice work! Now let's calculate the total number of sales for the month.

* Create a new column called "Total Sales" that uses SUMIF() to calculate the total Sales Amount for the Sales Month.
* Format this column as a $ with 0 decimals.

**Hint**

* The SUMIF() formula should look like this:

=SUMIF(Sales[\_\_\_\_],[@[Sales Month]],Sales[\_\_\_\_])

* The first month, 7/1/2020, should have $28,325 total sales.

6.

Create a new column called "Avg Sales Per Customer" that uses AVERAGEIF() to average the Total Sales by Number of Customers. Format accordingly.

Hint

There are two possible solutions:

* Divide Total Sales by Number of Customers.
* Use AVERAGEIF((Sales[\_\_\_\_],[@[\_\_\_\_]],Sales[Sales Amount]).
* Format this column as a $ with 0 decimals**.**

7.

**Which of these statements is true?**

* Total sales were $68,155 for 4/1/2021.
* Total sales is increasing while average sales per customer is decreasing.
* The share of Basic customers must be increasing.

**Hint**

* The Number of Customers formula should be:

=COUNTIF(Sales[Sales Month],[@[Sales Month]])

* The Total Sales formula should be:

=SUMIF(Sales[Sales Month],[@[Sales Month]],Sales[Sales Amount])

* The Avg Sales Per Customer formula should be:

=AVERAGEIF(Sales[Sales Month],[@[Sales Month]],Sales[Sales Amount])

*If you're still stuck, review the solution in 2\_3\_countif\_sumif.xlsx from the Workbooks folder.*

**COUNTIFS and SUMIFS**

1.

Because Avg Sales Per Customer is decreasing while Total Sales is increasing, one hypothesis for this relationship could be that the share of non-paying customers ("Basic" subscriptions) are growing faster than our paying customers.

* Create a new column called "Non-Paying Customers" that uses COUNTIFS() to count the number of customers with a Basic subscription for the Sales Month.
  + Remember to use "" when specifying a text criteria.
* **Hint**
* The formula should look like this: =COUNTIFS(Sales[\_\_\_\_],\_\_\_\_,Sales[Subscription Type],"\_\_\_\_").

2.

Great, now let's find the number paying customers so we can compare the two cohorts.

* Create a new column called "Paying Customers" using COUNTIFS() to counts the number of customers that are **not** Basic subscribers.
  + Use "<>\_\_\_\_" to exclude a given value from the count.

**Hint**

* The formula should look like this: =COUNTIFS(Sales[\_\_\_\_],\_\_\_\_,Sales[Subscription Type],"<>\_\_\_\_").

3.

The best way to compare two variables against each other is to create a ratio. Ratios are powerful because they can give a sense of scale.R

* Create a new column called "Basic to Paying Ratio" that is the ratio of Non-Paying Customers to Paying Customers.
* Format this as a number with 2 decimal places.

**Hint**

* The formula should look like this: =[@[Non-Paying Customers]]/[@[Paying Customers]].

4.

Interesting! It actually seems that the Basic to Paying Ratio has been decreasing drastically over the last 12 months. So now that we know the share of Basic customers is actually decreasing, it could lead to another hypothesis: the Total Sales in another subscription category is changing. Let's split out our Total Sales by Subscription Type.

* Create three SUMIFS() formulas that calculate the Sales Amount for each Sales Tier within the Sales Month:
  1. One column called "Premium Sales" for Subscription Type = "Premium"
  2. One column called "Business Sales" for Subscription Type = "Business"
  3. One column called "Enterprise Sales" for Subscription Type = "Enterprise"
* Format these as a $ with 0 decimal places

*Hint: Once you create your first SUMIFS() formula, you can reuse it for the next two and just change the criteria for each Sales Tier.*

**Hint**

The SUMIFS() formulas should look like this:

1. Premium Sales: =SUMIFS(Sales[\_\_\_\_],Sales[Sales Month],\_\_\_\_,Sales[Subscription Type],"Premium")
2. Business Sales: =SUMIFS(Sales[Sales \_\_\_\_],Sales[Sales Month],\_\_\_\_,Sales[Subscription Type],"Business")
3. Enterprise Sales:=SUMIFS(Sales[Sales \_\_\_\_],Sales[Sales Month],\_\_\_\_,Sales[Subscription Type],"Enterprise")

5.

For several months, Enterprise Sales remained constant. It is worth investigating this subscription type further.

* Create a new column called "Enterprise Sales Share", which shows the ratio of Enterprise Sales and Total Sales.
* Format as a % with 0 decimal places.

**Hint**

* The formula should look like this: Enterprise Sales Share:=\_\_\_\_/[@[Total Sales]]

6.

**What is the Enterprise Sales Share percentage in June 2021? Format your answer as a whole number.**

**38**

**Hint**

1. Non-Paying Customers should be:
   * =COUNTIFS(Sales[Sales Month],[@[Sales Month]],Sales[Subscription Type],"Basic")
2. Paying Customers should be:
   * =COUNTIFS(Sales[Sales Month],[@[Sales Month]],Sales[Subscription Type],"<>Basic")
3. Basic to Paying Ratio should be:
   * =[@[Non-Paying Customers]]/[@[Paying Customers]]
4. The sales share formulas should be:
   * Premium Sales: =SUMIFS(Sales[Sales Amount],Sales[Sales Month],[@[Sales Month]],Sales[Subscription Type],"Premium")
   * Business Sales: =SUMIFS(Sales[Sales Amount],Sales[Sales Month],[@[Sales Month]],Sales[Subscription Type],"Business")
   * Enterprise Sales: =SUMIFS(Sales[Sales Amount],Sales[Sales Month],[@[Sales Month]],Sales[Subscription Type],"Enterprise")
5. The Enterprise Sales Share formula should be:
   * Enterprise Sales Share: =[@[Enterprise Sales]]/[@[Total Sales]]

*If you're still stuck, review the solution in 2\_4\_countifs\_sumifs.xlsx from the Workbooks folder.*